[VB6] 還在用Inet控件（MSINET.OCX）嗎？這個模組簡單多了！

[複製鏈接]

ai1118

468 主題	0 好友	522 積分

高級會員

Rank: 4

UID: 70473
帖子: 471
主題: 468
精華: 0
積分: 522
楓幣: 738
威望: 521
存款: 0
贊助金額: 0
推廣: 0
ＧＰ: 43
閱讀權限: 50
性別: 保密
在線時間: 28 小時
註冊時間: 2014-7-14
最後登入: 2015-5-16

發消息

電梯直達

1樓

發表於 2014-7-14 09:14:29 |只看該作者 |倒序瀏覽

Author: Inndy
Source: 別再用MSINET.OCX了，用這個模組簡單多了

這個模組能做甚麼?他能取代VB控件Inet，更簡單更活用，也不必再調用MSINET.OCX就能用VB讀取網路上的文字資料！

請在VB當中新增一個模組 modDownload

' HTTP Downloading Module By Inndy
Option Explicit
' For API
Private Const CP_ACP = 0 ' default to ANSI code page
Private Const CP_UTF8 = 65001 ' default to UTF-8 code page
Private Declare Function MultiByteToWideChar Lib "kernel32" (ByVal CodePage As Long, ByVal dwFlags As Long, ByVal lpMultiByteStr As Long, ByVal cchMultiByte As Long, ByVal lpWideCharStr As Long, ByVal cchWideChar As Long) As Long
Private Declare Function WideCharToMultiByte Lib "kernel32" (ByVal CodePage As Long, ByVal dwFlags As Long, ByVal lpWideCharStr As Long, ByVal cchWideChar As Long, ByVal lpMultiByteStr As Long, ByVal cchMultiByte As Long, ByVal lpDefaultChar As Long, ByVal lpUsedDefaultChar As Long) As Long
' For module
Public Enum Encode
ANSI = 0
BIG5 = 1
UTF8 = 2
End Enum
Private Function ToUTF8(ByVal sData As String) As Byte()
Dim aRetn() As Byte, nSize As Long
nSize = WideCharToMultiByte(CP_UTF8, 0, StrPtr(sData), -1, 0, 0, 0, 0)
ReDim aRetn(0 To nSize - 1) As Byte
WideCharToMultiByte CP_UTF8, 0, StrPtr(sData), -1, VarPtr(aRetn(0)), nSize, 0, 0
ToUTF8 = aRetn
End Function
Private Function FromUTF8(ByVal sData As String) As Byte()
Dim aRetn() As Byte, nSize As Long
nSize = MultiByteToWideChar(CP_UTF8, 0, StrPtr(sData), -1, 0, 0)
ReDim aRetn(0 To 2 * nSize - 1) As Byte
MultiByteToWideChar CP_UTF8, 0, StrPtr(sData), -1, VarPtr(aRetn(0)), nSize
FromUTF8 = aRetn
End Function
Public Function DownloadData(ByVal url As String) As Byte()
Dim http As Object
Set http = CreateObject("MSXML2.ServerXMLHTTP")
http.Open "GET", url, False
http.setRequestHeader "Pragma", "no-cache"
http.send
DownloadData = http.responseBody
Set http = Nothing
End Function
Public Function DownloadString(ByVal url As String, Optional ByVal EncType As Encode = Encode.BIG5) As String
If EncType = Encode.ANSI Then
DownloadString = DownloadData(url)
ElseIf EncType = Encode.BIG5 Then
DownloadString = StrConv(DownloadData(url), vbUnicode)
Else
DownloadString = FromUTF8(DownloadData(url))
End If
End Function
Public Function DownloadFile(ByVal url As String, ByVal file As String) As Boolean
On Error GoTo Failed
Dim f As Integer
f = FreeFile
Open file For Binary As f
Put f, , DownloadData(url)
Close f
DownloadFile = True
Exit Function
Failed:
DownloadFile = False
End Function